Running a command(s) when closing Quicken

CHess1201

Let's say every time I close Quicken I want to run a command, something like:
Copy C:\Users\ersat\Documents\Quicken\MY_Quicken.QDF ​D:\Quicken

Is there a way to do this?

Chris_QPW

The way to do that is make your own command script.  Say Quicken.cmd (NotePad can create the file as long as you save it or renaming it to have the .cmd type).

Here example of a command script that copies a QDF file from the user's Dropbox folder to a temporary folder (c:\Quicken), runs it from there, and then when finished copies it back.

Note that you could put this script on your Desktop, or put where you like and create a shortcut to it, to run it:

@echo off

set DATA_FILE=Current.qdf

set DATA_DIR=c:\Quicken

set QUICKEN_DROPBOX_DIR=%USERPROFILE%\Dropbox\Quicken

copy "%QUICKEN_DROPBOX_DIR%\%DATA_FILE%" "%DATA_DIR%\%DATA_FILE%"

IF %ERRORLEVEL% == 0 GOTO COPY_PASSED

start /wait cmd /C "ECHO %QUICKEN_DROPBOX_DIR%\%DATA_FILE% copy of data file failed. && PAUSE"

GOTO END

:COPY_PASSED

"%ProgramFiles(x86)%\Quicken\qw.exe" "%DATA_DIR%\%DATA_FILE%"

copy "%DATA_DIR%\%DATA_FILE%" "%QUICKEN_DROPBOX_DIR%\%DATA_FILE%"

IF %ERRORLEVEL% == 0 GOTO END

start /wait cmd /C "ECHO %DATA_DIR%\%DATA_FILE% copy of data file failed. && PAUSE"

:END


For a dead simple example of what you requested:

@echo off

"%ProgramFiles(x86)%\Quicken\qw.exe" "C:\Users\ersat\Documents\Quicken\MY_Quicken.QDF"
Copy C:\Users\ersat\Documents\Quicken\MY_Quicken.QDF ​D:\Quicken