FAQ Script for copying your Quicken data out of a cloud folder and back into it.

Chris_QPW

It isn't recommended to keep the Quicken data file you are going to open in a cloud folder. Also, it isn't recommended to use Backup and Restore to move a data file back and forth between two machines when you will be doing it frequently. You can keep the Quicken data file in the cloud folder if you turn of syncing while using the data file in Quicken, but that is hard to remember to do. Below is a script that shows how to copy a Quicken data file out of OneDrive to a local drive and open it in Quicken, and then when Quicken closes copy it back. By changing the path from a OneDrive path to where Dropbox or other cloud folders keep the files you can use it with different cloud folder programs.

@echo off

set DATA_FILE=Current.qdf

set DATA_DIR=c:\Quicken

set QUICKEN_DROPBOX_DIR=%USERPROFILE%\OneDrive\Documents\Quicken\
IF EXIST %DATA_DIR% GOTO DIR_EXISTS

mkdir %DATA_DIR%

:DIR_EXISTS
copy "%QUICKEN_DROPBOX_DIR%\%DATA_FILE%" "%DATA_DIR%\%DATA_FILE%"
IF %ERRORLEVEL% == 0 GOTO COPY_PASSED

start /wait cmd /C "ECHO %QUICKEN_DROPBOX_DIR%\%DATA_FILE% copy of data file failed. && PAUSE"

GOTO END
:COPY_PASSED

"%ProgramFiles(x86)%\Quicken\qw.exe" "%DATA_DIR%\%DATA_FILE%"
copy "%DATA_DIR%\%DATA_FILE%" "%QUICKEN_DROPBOX_DIR%\%DATA_FILE%"

IF %ERRORLEVEL% == 0 GOTO END

start /wait cmd /C "ECHO %DATA_DIR%\%DATA_FILE% copy of data file failed. && PAUSE"
:END

Here is how to use the above script:

Edit the QDF file name and change the "set" lines as needed. Above, QDF file is called Current.qdf, it resides in the standard place of Documents\Quicken (in OneDrive), %USERPROFILE% is your user folder. The "local folder/copy" where it will be copied to and run Quicken from is the folder c:\Quicken, which will be created if it doesn't already exist.

File → Save, save it to whatever folder you like, with whatever name you like, but you have to end the name with .cmd. That makes it a "script". Note I don't suggest the Desktop, for this file. The reason will be, because you will most likely want to make a shortcut to this file and put that on your Desktop. Your Documents folder is a good place for it.

If you double click on the "Quicken.cmd" file In Windows File Explorer it will copy the data file to the DATA_DIR and then open Quicken with that data file. It will copy it back when you close Quicken.

If you right click (Hold down shift key on Windows 11) on the "Quicken.cmd" file in Windows File Explorer you will get the context menu and can select Send to → Desktop (create shortcut).

Now you can use that shortcut in the same way. You can also rename it, and if you right click on it and select Properties you can change Run to Minimized so that will stay as an icon in your task bar.

Note as a bonus, say you are working on something in Quicken and things go bad. If you close the command script in the task bar before closing Quicken the data file will not be copied back, allowing you not overwrite your last copy in your Documents folder. That is also a warning not to close it if you want it copied back.

When running:

The black icon is the command script when running.

You might also want to add the c:\Quicken (or wherever you put as the DATA_DIR in the script) to the Windows File Explorer Quicken access list so that you can get to this folder quickly if needed.