Quicken Data in the Cloud

You mentioned Windows and Mac laptops. Quicken Windows and Quicken Mac data files/programs aren't compatible with each other so whereas it is possible to setup a system where two Quicken Windows laptops get "access" to the data file at separate times, there isn't any way to do that from a Mac laptop unless it is running Windows in a Virtual Machine. And the reverse is true for Quicken Mac.

@Jim_Harman is correct that the lock Quicken puts on the data file will not carry over to services like the "cloud folders" on the remote machine(s). It "somewhat" carries over to network drives but given all the possibilities of different network configurations this locking isn't 100%. And to compound that problem is what Quicken is doing with the locking. Basically, Quicken is depending on the fact that when it opens the data file it uses a flag to let Windows know to not allow any other application to access it. But there are times where Quicken will close the data file (which removes the lock) and then expects to open it shortly afterwards, which creates some short periods of time where the data file isn't locked, and if the "cloud service" goes to do the sync at that time it will cause problems.

I can see a way to implement this though, but I doubt Quicken Inc would implement it. That wouldn't stop the user from doing it though using a script.

Let me say right off the bat, you do not want to use backup and restore for this. Restore "syncs the data file" and repeated use of it can cause problems.

Your actual goal is to always use the most current copy of the data file. Quicken doesn't have problems "syncing" from different locations. What it has problems with can be shown this way. You have to imagine your data file as being split into two parts.

Part A, the data file on your computer.

Part B, the data that is in sync with it in the Quicken Cloud dataset.

You open your data file and do anything with an online service you have to assume something matching was changed in the Quicken Cloud dataset too.

If you take a copy of the current data file on another machine and it connects to the Quicken Cloud dataset, that will work fine. But as you noted if that later you now connect with that "unchanged data file" on the first machine they will be out of sync and that can cause problems.

What will get you 95% to this goal is simply automating copying your data file from/to the cloud folder.

With this, as long as you close the data file on each machine after use (both of which are setup with this automation), it should work fine.

The "script" looks like:

• Copy data file from cloud folder to local folder.
• Run Quicken with the local data file (script wait for Quicken to close).
• Copy data file from local folder to cloud folder.

To get to about 99% would be to introduce a lock file. It isn't 100% because timing issues, but assuming that the opening of the data file on the other machine "takes time" it would be very close to 100%.

Above just changes to this:

• Check if the there is a lock file in the cloud folder, and if is there print a message and exit.
• Create the lock file in the cloud folder.
• Copy data file from cloud folder to local folder.
• Run Quicken with the local data file (script wait for Quicken to close).
• Copy data file from local folder to cloud folder.
• Delete the lock file in the cloud folder.

The following script does this. To use this, you would create a file with Notepad and copy this below into the file. Then when saving it out make sure you change the .txt file type in the name to .cmd. You can call the file whatever you like. You need to edit DATA_FILE, LOCAL_DATA_DIR, and QUICKEN_REMOTE_DIR to reflect your setup.

@echo off


set DATA_FILE=Current.qdf

set LOCAL_DATA_DIR=c:\Quicken

set QUICKEN_REMOTE_DIR=%USERPROFILE%\OneDrive\Documents\Quicken

set LOCK_FILE=%QUICKEN_REMOTE_DIR%\%DATA_FILE%.lock


IF EXIST "%LOCAL_DATA_DIR%" GOTO DIR_EXISTS

mkdir %LOCAL_DATA_DIR%

:DIR_EXISTS


IF NOT EXIST "%LOCK_FILE%" GOTO NO_LOCK_FILE

start /wait cmd /C "ECHO %LOCK_FILE% exists, Exiting. && PAUSE"

GOTO SKIP_DELETE


:NO_LOCK_FILE


ECHO "Quicken Lock File" > "%LOCK_FILE%"


copy "%QUICKEN_REMOTE_DIR%\%DATA_FILE%" "%LOCAL_DATA_DIR%\%DATA_FILE%"


IF %ERRORLEVEL% == 0 GOTO COPY_PASSED

start /wait cmd /C "ECHO %QUICKEN_REMOTE_DIR%\%DATA_FILE% copy of data file failed. && PAUSE"

GOTO END


:COPY_PASSED

"%ProgramFiles(x86)%\Quicken\qw.exe" "%LOCAL_DATA_DIR%\%DATA_FILE%"


copy "%LOCAL_DATA_DIR%\%DATA_FILE%" "%QUICKEN_REMOTE_DIR%\%DATA_FILE%"

IF %ERRORLEVEL% == 0 GOTO END

start /wait cmd /C "ECHO %LOCAL_DATA_DIR%\%DATA_FILE% copy of data file failed. && PAUSE"


:END


del "%LOCK_FILE%"


:SKIP_DELETE

To run this you just double click on the *.cmd file you created.